Matematické Fórum

kill(all); 
load("opsubst");
Par(X,Y):=X*Y/(X+Y);

Najdi(R, G):=block([M, N, P, S, D:[], Q:0, J, K:0],
    N: gcd(R,G),
    M: R/N,
    N: G/N, 
    while is(N>0 and M>0) do (
        K: K+1,
        if N<M then (
            M: M-N,
            D: cons(P,D)            
        ) else(
            N: N-M,
            D: cons(S,D)
        )      
    ), print("Počet odporů:",K),
    for J:1 thru length(D) do (
        if D[J]=S then Q: Q+R else Q:'Par(Q,R)
    ), opsubst("Par", "Par", Q)
)$
compile(Najdi);

Najdi(1000, 420);
ev(%);

Počet odporů: 9
Par(Par(Par(Par(2000,1000)+1000,1000)+2000,1000),1000)
420

kill(all); 
load("opsubst");
Par(X,Y):=X*Y/(X+Y);

Kombinace(Rz, W, N):= block([Q:[], R],    
    Komb(U, X, Y, H, S):=block([Z, T],
        if H<N then (
            
            /* Sériově - doleva */
            Z: float(X+Y), 
            T: S+R, 
            if abs(Z-W)<1e-8 then (
                Q: cons(T, Q)
            ) else (                
                Komb(U, Z, U, H+1, T)
            ), 
            
            /* Sériově - doprava */
            Z: float(X+Y), 
            T: R+S, 
            if abs(Z-W)<1e-8 then (
                Q: cons(T, Q)
            ) else (                
                Komb(U, U, Z, H+1, T)
            ), 
            
            /* Paralelně - doleva */
            Z: float(X*Y/(X+Y)), 
            T: 'Par(S,R), 
            if abs(Z-W)<1e-8 then (
                Q: cons(T, Q) 
            ) else (            
                Komb(U, U, Z, H+1, T)
            ),
            
            /* Paralelně - doprava */
            Z: float(X*Y/(X+Y)), 
            T: 'Par(R,S), 
            if abs(Z-W)<1e-8 then (
                Q: cons(T, Q) 
            ) else (            
                Komb(U, Z, U, H+1, T)
            )
        ) 
    ),
    Komb(Rz, Rz, Rz, 0, R),  Q
)$ 
compile(Kombinace);


showtime: all$  
/* první parametr - jednotná hodnota použitých odporů */
/* Druhý parametr - cílová hodnota odporu */
/* Třetí parametr - počet spojení (sériových a paralelních) pro 9 odporů to dělá 8 spojení */
L: Kombinace(1000, 420, 8)$
L: unique(sort(L))$ /* vyloučí opakující se zapojení */
showtime: false$
Vzorce: opsubst("Par", "Par", at(L, R=1000)); /* výpis všech nalezených zapojení */
Value: ev(Vzorce); /* číselné vyhodnocení všech zapojení pro kontrolu - musí dát 420 Ω */
length(Value); /* počet všech platných řešení */